The applet requires Java 5 or higher. Java must be enabled in your browser settings. Mac users must have Mac OS X 10.4 or higher. Windows and Linux users may obtain the latest Java from Oracle's Java site.
This model is showing the aggregation tendencies of Dictyostelium discoideum.
The "leader" cell in the middle (colored in blue) sends out a circle of cAMP chemicals. When a Dicty cell senses a cAMP closeby, it moves towards it, and immediately experiences a "refractory" period (cell is colored pink), in which the cell does not respond to cAMP. Once the refractory period is over, the cell returns to its natural color of cyan, and it is receptive again. The model stops once all cells have aggregated to the leader.
Press "setup", and then "go". Note that in the initial settings, the Dicty cells do not aggregate. Play around with the two sliders: time-between-waves, and refractory-time. They are both self-explanatory. Time-between-waves changes the amount of "ticks" between cAMP waves. Refractory-time changes the amount of ticks that a Dicty cell is in its "refractory" mode.
Notice that initially, the Dicty cells are in limbo; they seem to move back and forth without any real progress. See what other types of behavior you can produce from the Dicty cells.
Naturally, play with the sliders and see what settings will yield an aggregate result. Also, the draw-paths switch will show a trail where each Dicty was.
One key choice by the developer was how big of a radius of vision to give the Dicty cells. Changing this may cause different results. In the "respond" method, observe the first two lines, in which the cells look to see if any cAMPs are within a radius of 2. Changing this will change the radius of vision. To do this, one would need to download the model and run it on your own machine.
Similar to “Slime” model built by Uri W. However, this model has clear leaders which are sending out chemicals.
Credit is due to Victoria G. Rinker, Pooja Potharaju, Laurie J. Heyer, and A. Malcolm Campbell for their work on the "Slime-U-Lator (slime mold simulation)" in Excel.
breed [cAMPs cAMP] ;cAMP is chemical that leader sends off to attract more Dicty cells
breed [dictys dicty]
breed [leaders leader]
dictys-own [
refractory? ;boolean value representing whether Dicty is in refractory phase.
time-since-move ;used to determine refractory period of Dicty.
]
to setup
clear-all
reset-ticks
setup-background
setup-turtles
end
to setup-background
let radius 16
set-default-shape leaders "square"
create-leaders 1 [
set color blue
]
ask patches [
ifelse (distancexy 0 0 ) >= radius
[set pcolor black]
[set pcolor (brown + 3)] ] ;color #38 ( = brown + 3) is used to represent agar (in petri dish)
end
;;Dicty cells are randomly placed in "petri dish"
to setup-turtles
set-default-shape cAMPs "square"
while [count dictys < initial-dictys][
create-dictys 1 [
set refractory? false
set color cyan
set xcor random-xcor set ycor random-ycor
if pcolor = black [die]
]
]
end
to go
ask cAMPs [ ;cAMP chemical spreads (diffuses) out.
fd 1
if pcolor = black [die]
]
ask dictys [
if draw-paths? [pen-down]
set time-since-move time-since-move + 1
if time-since-move > refractory-time [
set refractory? false
set color cyan]
if not refractory? [
respond
]
]
if ticks mod time-between-waves = 0 [
release-chemical]
tick
if all? dictys [distancexy ([xcor] of one-of leaders) ([ycor] of one-of leaders) < 1.5] [
user-message "Dicty cells hace converged"
stop]
end
to respond
if any? cAMPs in-radius 2 [
face min-one-of cAMPS in-radius 2 [distance myself]
if distance leader 0 > 1 [
fd 1
set time-since-move 0
set refractory? true
set color pink
]
]
end
to release-chemical
let amount-of-cAMPS 80
create-cAMPs amount-of-cAMPS [
set color red
set xcor 0
set ycor 0
set heading (who * 360 / amount-of-cAMPS + (random-float 2) - 1) ;slight variance in the heading of the chemical
]
end
|